Win11右键菜单怎么添加画图程序

Win11右键菜单怎么添加画图程序: 2024-01-19 11:03:11 分类：帮助

Windows 11 64位 23H2 专业版 V2024.03

发布时间：2024-02-18
大小：5.11 GB
下载次数：233

本地下载

Win11系统更新后，许多用户发现右键菜单中缺少了画图程序，而画图程序在日常使用中非常方便。本文将介绍如何在Win11系统中添加画图程序到右键菜单，让用户可以更方便地使用这一功能。

步骤一：

1、按【 Win + X 】组合键，或【右键】点击任务栏上的【Windows开始徽标】，打开的右键菜单项中，选择【运行】；

2、运行窗口，输入【cmd】命令，然后按【 Ctrl + Shift + Enter 】组合键；

3、用户账户控制窗口，你要允许此应用对你的设备进行更改吗？点击【是】；

4、管理员命令提示符窗口，输入并按回车执行以下命令：

reg.exe add "HKCU\Software\Classes\CLSID\{86ca1aa0-34aa-4e8b-a509-50c905bae2a2}\InprocServer32" /f /ve

5、接着，【右键】点击任务栏上的空白处，在打开的项中，选择【任务管理器】；

6、任务管理器窗口，找到并选择【Windows 资源管理器】，再点击右上方的【重启任务】；

7、最后，就可以看到展开的右键菜单了；

步骤二：

1、在桌面空白的地方，点击【右键】，打开的右键菜单项中，选择【新建 - 文本文档】；

2、新建文本文档 - 记事本窗口，输入以下命令：

@echo off
(PUSHD "%~DP0")&(REG QUERY "HKU\S-1-5-19">NUL 2>&1)||(powershell -Command "Start-Process '%~fdpnx0' -Verb RunAs"&&EXIT)
title 在Win11下给图片右键添加"用画图编辑"
for /f "tokens=4 delims= " %%a in ('ver') do (for /f "tokens=1 delims=." %%b in ("%%a") do set num=%%b)
if %num% LSS 10 echo 你的系统无需此操作按任意键退出&pause>NUL&exit
reg query "HKCR\Local Settings\Software\Microsoft\Windows\CurrentVersion\AppModel\PackageRepository\Extensions\ProgIDs\AppXcesbfs704v2mjbts9dkr42s9vmrhxbkj">nul 2>nul
if %errorlevel% == 1 echo 未安装画图按任意键退出&pause>NUL&exit
set /a menu=0
echo 在Win11下给图片右键添加"用画图编辑"&echo=&echo 1、添加或修复右键菜单 (由于微软频繁的自动更新程序所以需要经常修复)&echo=&echo 2、删除右键菜单&echo=
set /p menu=请选择功能 (默认 %menu% 不做更改直接退出):
if %menu%==0 exit
if %menu%==1 goto 1
if %menu%==2 goto 2
:1
cls
echo 正在添加或修复右键菜单请稍候...
for /f "tokens=1* delims= " %%a in ('reg query "HKCR\Local Settings\Software\Microsoft\Windows\CurrentVersion\AppModel\PackageRepository\Extensions\ProgIDs\AppXcesbfs704v2mjbts9dkr42s9vmrhxbkj"') do set mspaint=%ProgramFiles%\WindowsApps\%%a\PaintApp\mspaint.exe
set all=avci,avif,bmp,dib,emf,gif,heic,heif,hif,ico,jfif,jpe,jpeg,jpg,png,rle,tif,tiff,webp,wmf
for %%i in (%all%) do ( REG delete HKCU\Software\Classes\SystemFileAssociations\.%%i\shell\用画图编辑 /f /reg:64>nul 2>nul
REG ADD "HKCU\Software\Classes\SystemFileAssociations\.%%i\shell\用画图编辑" /v "icon" /t REG_SZ /d "%mspaint%" /f /reg:64>nul
REG ADD "HKCU\Software\Classes\SystemFileAssociations\.%%i\shell\用画图编辑\Command" /v "" /t REG_SZ /d "\"%mspaint%\" \"%%1\"" /f /reg:64>nul
)
cls
echo 操作完成请按任意键退出&pause>NUL&exit
:2
cls
echo 正在删除右键菜单请稍候...
set all=avci,avif,bmp,dib,emf,gif,heic,heif,hif,ico,jfif,jpe,jpeg,jpg,png,rle,tif,tiff,webp,wmf
for %%i in (%all%) do ( REG delete HKCU\Software\Classes\SystemFileAssociations\.%%i\shell\用画图编辑 /f /reg:64>nul 2>nul )
cls
echo 删除完成请按任意键退出&pause>NUL&exit